This seems to occur specifically in a mixed-frequency graph; my suspicion is that the line-style setting is not being applied (or is being overridden) in the mixed-frequency rendering routine. I’ve attached (1) the EViews graph object/output and (2) the code used to generate the graph so you can reproduce the issue. Could you please investigate and fix this issue?
Version: EViews 14 jan5 2026
- 1.jpg (56.36 KiB) Viewed 8704 times
- 2.jpg (61.98 KiB) Viewed 8704 times
Program:
Code: Select all
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Dette programmet plotter boliginvesteringer og realboligpriser. Først spesifiserers
' navn på grafen, overskrift, underoverskrift og kildehenvisning. Språk og nummerering
' avhenger av hvorvidt figuren skal i KT eller ES eller på Powerpoint slides (i bredt format).
' Fastprisåret defineres i masterfilen. Formatering av skriften skjer lenger ned i programmet.
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Programargumentet velger norsk eller engelsk figurtekst, med eller uten figurnummerering
!count = !count +1 ' increase figure number
%nr = @str(!count) ' make the number into a string
if %spraak = "Norsk" then
%gr = "boligmarkedet" 'displaynavnet i spoolobjektet
%underoverskrift1 = "Sesongjustert, indeks, " + %fastprisaar + " = 100"
%kilde = "Kilde: Statistisk sentralbyrå"
'Spesifiserer navnet (legend) for de inkluderte seriene.
%serie1 = "Nominelle bruktboligpriser "
%serie2 = "Reelle bruktboligpriser "
%serie3 = "Boliginvesteringer"
%serie4 = "Nominelle nyboligpriser"
if %figur = "KT" then
%hovedoverskrift = "Figur 2."+%nr+". Boligmarkedet"
else '%figur = "Powerpoint", dermed intet figurnummer
%hovedoverskrift = "Boligmarkedet"
%underoverskrift1 = "Sesongjustert. Indeks, " + %fastprisaar + " = 100" ' Høyre akse: mrd "+ %fastprisaar + "-kr, kvartal og måned"
endif
else '%spraak = "Engelsk"
%gr = "housing_market"
%underoverskrift1 = "Seasonally adjusted, index, " + %fastprisaar + " = 100"
%kilde = "Source: Statistics Norway"
%serie1 = "Nominal 2nd-hand housing prices"
%serie2 = "Real 2nd-hand housing prices"
%serie3 = "Housing investment"
%serie4 = "Nom. new home prices"
if %figur = "KT" then
%hovedoverskrift = "Figure "+%nr+". Housing market"
else '%figur = "Powerpoint", dermed intet figurnummer
%hovedoverskrift = "Housing market"
endif
endif
if @isobject(%gr) = 1 then
delete {%gr}
endif
'Kan fastsette range på aksene. Hvis ikke noe er spesifisert genereres det automatisk.
%leftaxisrange = "58,130"
%rightaxisrange = "58,130"
' Kopierer serier og ager glatt prediksjonsserier ved hjelp av addin-programmet kvarts_sa
'wfselect {%data_workfile} ' gjør til aktiv workfile
pageselect q
smpl @all
kvarts_sa(level) pbol pbol_gg ' nominell boligpris
'kvarts_sa(level) jks83 jks83_gg ' boliginvesteringer
copy kvarts\pbol_sa_h_real pbol_real_sa
copy kvarts\pbol_sa_h_real kvarts\pbol_real ' for linje 80 i addin programmet kvarts_sa
kvarts_sa(level) pbol_real pbol_real_gg ' realboligpris
' Beregning av boliginvesteringer som indeks
ps m
smpl @all
kvarts_sa jks83
genr jks83_h = jks83_sa*3/1000000
smpl {%fastprisaar}m1 {%fastprisaar}m12
!aarsgjennomsnitt = @mean(jks83_h)
smpl !startyear 2016q1
genr jks83_h = q\jks83_sa
smpl @all
genr jks83_hh = 100*jks83_h/!aarsgjennomsnitt
%sisteobs = jks83.@last ' siste måned med observasjon/verdi
smpl {%sisteobs} !endyear ' @now-3 !endyear
genr jks83_gg = jks83_sa_kt*3/1000000
jks83_gg = 100*jks83_gg/!aarsgjennomsnitt
ps q
smpl {%fastprisaar}q1 {%fastprisaar}q4
!aarsgjennomsnitt = @mean(pbol_sa)
!aarsgjennomsnitt_ny = @mean(pbol_ny)
'Lager grafen
wfselect {%data_workfile} ' gjør til aktiv workfile
pageselect kvarts
smpl !startyear !endyear
graph {%gr}.line(x) q\pbol_sa*100/!aarsgjennomsnitt q\pbol_gg*100/!aarsgjennomsnitt m\jks83_hh m\jks83_gg q\pbol_real_sa*100 q\pbol_real_gg*100 q\pbol_ny*100/!aarsgjennomsnitt_ny
'Setter størrelsen på grafen
{%gr}.options linepat size({!width}, {!height})
'Formaterer akser og støttelinjer
{%gr}.options frameaxes(lbrt) framewidth(0.5) gridwidth(0.5) gridcolor(ltgray) ' gridl(7) gridr(7)
'Formaterer aksene
{%gr}.axis(l) range({%leftaxisrange}) font(Open Sans,13,-b,-i,-u,-s)
{%gr}.axis(r) range({%rightaxisrange}) font(Open Sans,13,-b,-i,-u,-s) ticksnone
{%gr}.axis(b) units(n) font(Open Sans,13,-b,-i,-u,-s)
{%gr}.options -gridr gridcust(year, 1)
{%gr}.datelabel interval(year, 2, {!endyear}) span(between) '
'Formaterer seriene. Note: hvis det lages en graf med to akser ( line(x) ) så vil første serie måles på venstre akse og alle andre på høyre akse hvis ikke annet spesifiseres.
{%gr}.setelem(1) linecolor(@rgb({%gronn3})) legend(%serie1) axis(l) linewidth(!linewidth)
{%gr}.setelem(2) linecolor(@rgb({%gronn3})) linepattern({%dashline}) legend() axis(l) linewidth(!linewidth)
{%gr}.setelem(3) linecolor(@rgb({%gul3})) linepattern(solid) legend(%serie3) axis(r) linewidth(!linewidth)
{%gr}.setelem(4) linecolor(@rgb({%gul3})) linepattern({%dashline}) legend() axis(r) linewidth(!linewidth)
{%gr}.setelem(5) linecolor(@rgb({%lilla5})) linepattern(solid) legend(%serie2) axis(l) linewidth(!linewidth)
{%gr}.setelem(6) linecolor(@rgb({%lilla5})) linepattern({%dashline}) legend() axis(l) linewidth(!linewidth)
{%gr}.setelem(7) linecolor(@rgb({%oransj4})) linepattern(solid) legend(%serie4) axis(r) linewidth(!linewidth)
'legger til overskrift, underoverskrifter, kilde og legend
if %figur = "KT" then
{%gr}.addtext(-0.4, -0.7, textcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans Semibold,16,b,-i,-u,-s)) %hovedoverskrift
{%gr}.addtext(-0.4, -0.4, textcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans,14,-b,-i,-u,-s)) %underoverskrift1
{%gr}.addtext(-0.4, 4.1, extcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans,12,-b,-i,-u,-s)) %kilde
{%gr}.legend columns(2) -inbox position(0, 3.4) font(Open Sans,14,-b,-i,-u,-s)
else '%figur = "Powerpoint
{%gr}.addtext(-0.4, -0.9, textcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans Semibold,20,b,-i,-u,-s)) %hovedoverskrift
{%gr}.addtext(-0.4, -0.5, textcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans,14,-b,-i,-u,-s)) %underoverskrift1
{%gr}.addtext(-0.4, 4.9, textcolor(@rgb(0,0,0)), fillcolor(@rgb(255,255,255)), framecolor(@rgb(0,0,0)), just(l) , font(Open Sans,12,-b,-i,-u,-s)) %kilde
{%gr}.legend columns(3) -inbox position(0, 4.4) font(Open Sans,14,-b,-i,-u,-s)
endif
' Legger objektet til i spoolen
copy {%gr} kvarts\{%gr}
pageselect kvarts
graphs.append(name={%gr}) {%gr}
' Spar figuren med spesielt navn i spesiell mappe for default aksess fro layoutdamene
%sti_og_filnavn = %SharePoint_sti_pdf + %nr
{%gr}.save(t=pdf, c, box, port, w=5.5, h = 3, u=in, d=300, trans) {%sti_og_filnavn}
%sti_og_filnavn = %SharePoint_sti_png + %nr
{%gr}.save(t=png, d=800) {%sti_og_filnavn} ' får ikke med stiplinger i EViews 14
' Hvis figur er til Powerpoint slides lagres den på disk
if %figur = "Powerpoint" then
%mappe = @runpath
{%gr}.save(t=jpg,d=800) {%mappe}\Figurer_til_Powerpoint_slides\{%gr}
endif