Page 1 of 1
lag in MIDAS
Posted: Mon Dec 24, 2018 9:52 pm
by Jcool
Hi,
I am currently using MIDAS in Eviews. Looking at the example (see attached) on Eviews web, the estimated result shows the estimated coefficients of the high-frequency independent variables and it starts from lag1 onwards.
Working on my data (see the file under the name of "query"), I couldn't get Eviews to show the estimated coefficients of the high-frequency independent variables from lag1. May I know if there is a way that I can adjust the setting to show estimated coefficients of the high-frequency independent variables from lag1 onwards?
Thank you.
Re: lag in MIDAS
Posted: Tue Dec 25, 2018 1:17 am
by EViews Gareth
No, we changed the labeling at some point to more accurately reflect. In the bottom picture you should minus 1 from the lag definitions.
Re: lag in MIDAS
Posted: Thu Dec 27, 2018 12:08 am
by Jcool
Thanks for the information.
May I please check with you if the estimated coefficient of lag0 captures the contemporaneous effect between the high-frequency (independent variable) and low-frequency (dependent variable)?
Thank you.
Re: lag in MIDAS
Posted: Thu Dec 27, 2018 10:14 am
by EViews Gareth
Depends on what you mean by contemporaneous (that term is complicated in a mixed frequency setting).
Here's a program that manually estimates an Almon lag model and computes the lags. You can see what's going on.
Code: Select all
!xlags = 4
!ylags=0
!horizon=-2
!polyorder = 3
close @wf
wfopen(wf=midas, page=quarterly) .\mydata.xlsx range="Sheet1"
pageload(page=monthly) .\mydata.xlsx range="Sheet2"
series x = dlog(value)*100
series x1 = dlog(value(-!horizon))*100
'create monthly lags
for !i=2 to !xlags
series x!i = x1(-!i+1)
next
for !i=1 to !xlags
series z!i=x!i(-2)
next
'copy monthly data over as individual time series, one for each lag.
pageselect quarterly
series y = dlog(value)*100
smpl 1985 2009/1/1
for !i=1 to !xlags
copy(c=l) monthly\z!i x!i
next
'create polynomial
for !i=1 to !polyorder
series z!i=0
next
for !i=1 to !xlags
for !j=1 to !polyorder
z!j = z!j + !i^(!j-1)*x!i
next
next
group xlags z*
group ylags
for !i=1 to !ylags
ylags.add y(-!i)
next
equation eq2.ls y c xlags ylags
show eq2
'calculate monthly lags
matrix(!xlags, !polyorder) a
for !i=1 to !xlags
for !j=1 to !polyorder
A(!i,!j) = !i^(!j-1)
next
next
'monthly lags = A*midas coefficients from equation.
vector mlags = A*@subextract(eq2.@coefs, 2,1,1+!polyorder,1)
show mlags
equation eq1.midas y c @ monthly\x
show eq1