close @all
%dir=@runpath
cd {%dir}
'---------------------
wfopen ..\kvarts
'---------------------

'snur modellen, dvs løser for rnokr slik at rnok når en bestemt bane 


'tar tiden
tic


'lagrer historisk serie for restleddet
copy rnok rnok_h



'1) eksogeniser rnok
_kvarts.drop rnok


'2) sett ønsket bane for rnok
smpl 2016:4 2018:4
	genr rnok =1.00/400
smpl 2018:4 2020
	genr rnok = 1.5/400


'3) endogeniser rnokr (snu ligningen)
_kvarts.add 0*rnokr+ d(rnok , 1) =  rnokr+ rnokr__1 + r__nok(1) + r__nok(2) * dumstep083 - r__nok(2) * dumstep094 + r__nok(3) * dum033 + r__nok(4) * dkv1 + r__nok(5) * rnok(-1) + r__nok(6) * d(rutl , 1) - r__nok(5) * rutl(-1) + r__nok(7) * d(log(kpijae) , 1) + r__nok(7) * d(log(kpijae(-1)) , 1) + r__nok(7) * d(log(kpijae(-2)) , 1) + r__nok(7) * d(log(kpijae(-3)) , 1) + r__nok(8) * urkorr(-1)


'4) løs modellen
smpl 2016 2020
_kvarts.solve


'tar tiden
toc
!elapsed =@toc


'resultater
smpl 2015 2020
graph gr_rnok.line rnok rnok_h
graph gr_rnokr.line rnokr_0 rnokr
text text_time
%time="Det tok "+@str(!elapsed)+ " sekunder å snu modellen manuelt"
text_time.append %time

spool results
results.add text_time
results.add gr_rnok
results.add gr_rnokr
show results