Marginal effects in Tobit Model

[Raupel]

Hello,

I am currently working on a tobit model since my dependent variable is truncated. Fortunately, my model turns out to be highly significant.

However, I am looking for a way to compute the marginal effects of the independent variables since the estimates are rather difficult to interpret.

Does somebody know whether Eviews (6.0) does incorporate a way to compute marginal effects in a tobit model?

Thanks for your help, it's highly appreciated!

Regards,
Manuel

[EViews Glenn]

There is nothing built-in. I'm assuming that you are interested in the derivatives of the conditional mean of the observed dependent, not the those of the latent dependent, since the latter are simply the beta coefficients.

The calculations depend a lot on the particulars of your specification (distribution, truncation thresholds, etc.) Can you provide more information about your exact specification?

[Raupel]

Hello,

thank you for your reply.

Indeed, I am interested in the marginal effects of the dependent variable, not in these of the latent one.

My dependent variable is truncated, with a lower limit of 0 and an upper bound of 1 since I estimate proportions. Furthermore, I assume a normally distributed dependent variable, my sample size is n=35 and I use both quantitative and ordinally scaled variables as regressors. I use robust covariances (Huber/White) and Quadratic Hill Climbing for ML estimation.

Thanks for any help, I am really grateful for it.

[EViews Glenn]

That's a moderately complicated specification, especially since you have both continuous and discrete regressors. Even in the best of circumstances, the derivatives of the expected observed Y are a bit messy since you have to worry about (among other things) the derivative of the expected value of the conditional error. In your case, that will be the derivative of the expected value of the doubly censored normal. It's not that hard to do this, but by the time we're done, it's going to get quite messy. That's for the continuous regressor case. In the discrete case, you simply have to evaluate the conditional mean at the different values of the discrete variable (which is somewhat easier).

Along the lines of the latter, here's what I'd recommend...

If I were you, I would save my equation into a model object. If you haven't worked with a model object before, it allows you to solve for the values of the dependent variable in your equation for various values of the regressor variables. In the time series context this generally means solving for values in a forecast-sample, but the idea is more general. To get the equivalent of the derivatives you asked for originally, you could, for example, set all of the independents to mean values as your baseline, then tweak values for a single variable to see the effect of the epsilon or the discrete change in value.

Alternately, you could leave all of the independents (but 1) at original values, and then compare for each individual the values for the dependent if we set the remaining dummy to 0 and then to 1.

The way this works is that the model object allows you to set up scenarios which allow you to solve the model using different counterfactual values for the regressors. This is a familiar concept to macro-model builders, but is something that cross-section people might also find useful. In your case, you could solve your model for any set of values for the regressor variables simply by creating the new series containing the alternate values of the regressor, and then telling the model to use a scenario that used the new series instead of the original.

While a bit more effort, this type of simulation is, in my view, far superior to the common practice of simply quoting marginal effects with X's at means (my discomfort with the latter is part of the reason that we don't offer derivatives as a built-in feature). Recall that In nonlinear specifications, where you evaluate the X's matters a great deal for derivative values, and it may well be that evaluation at means reports derivatives that are radically different from those faced by anyone (in or out-of-sample). The upside to the additional effort is that you get a lot more control over your comparisons, and you can ask much more interesting questions.

The model chapter of the User's Guide has an okay (not great) description of all of this. If you are interested in this approach you should take a look, give this some thought, and then if necessary, ask questions on the back-end.

[Raupel]

Dear QMS Glenn,

thank you very much for your detailed answer to my problem. Unfortunately, I currently do not have the time to implement your recommendations. However, as soon as I find some time I'll figure it out.

In case of additional questions, may I ask for your help again?

Cheers

[boydb]

Dear Glenn and Raupel,

I am having a similar problem with estimating the factor to adjust my co-efficients for interpretation. I have read the user guide (esp. pp. 213 and 222) and used the Forecast command on the equation toolbar and chosen Series to forecast: Index and the index is automatically named (in the guide it is named xb). The guide on p. 222 then says "Then the auto-series @dnorm(-xb), @dlogistic(-xb), or @dextreme(-xb) may be multiplied by the coefficients of interest to provide an estimate of the derivatives..." How do I calculate @dnorm(-xb) from the series xb? [I must be missing something simple]. If either of you can help I would be grateful.

Yours sincerely,

Boyd

[EViews Glenn]

Simple it is...

series densxb = @dnorm(-xb)

[boydb]

Thanks Glenn - I'll give that a crack. Are you are Star Wars fan? Regards, Boyd

[boydb]

HI Glenn,

I have tried as you suggested and I get a series which I assume are cumulative probabilities for each forecast. What do I do wth this series in order to get the single number adjustment factor?

Regards,

Boyd

[EViews Glenn]

HI Glenn,

I have tried as you suggested and I get a series which I assume are cumulative probabilities for each forecast. What do I do with this series in order to get the single number adjustment factor?

Regards,

Boyd

Boyd,

I'm not certain of the context in which you ask this last question. What exactly are you trying to compute?

[boydb]

Glenn - I am trying to compute the factor for adjusting the Tobit co-efficients so they can be interpreted as they can be for OLS. I am following Wooldridge (2000, p. 543): 'Equation (17.27) allows us to roughly compare OLS and Tobit estimates. The OLS coefficients are direct estimates of dE(y]x)/dxj. To make the Tobit estimates comparable, we multiply them by the adjustment factor at the mean values of xj, standard normal cdf(mean of x*MLE Beta/estimated sigma).' This is consistent with what is on page 222 of the Eviews 6 user guide II and with the example in Wooldridge (2000, p. 544 - here a factor of 0.451 is obtained) but what is produced through Eviews is the series and not a single adjustment factor. Are you suggesting I re-run the tobit with the new series as the dependent variable?

Reference:

Wooldridge, J.M. (2000) Introductory Econometrics: A Modern Approach, South Western College Publishing, Mason.

Regards,

Boyd

[EViews Glenn]

Got it...

What you are doing when you perform the forecast (or equivalently, a model solve) is to compute the xi'b at every observation i of the forecast (or model solution) sample. You can get your mean value by simply taking the mean of the forecasted xb values:

Since you mention the Wooldridge book, let's go ahead and replicate your calculation using that dataset:

Code: Select all

' First, grab the data and perform the estimation:
wfopen http://fmwww.bc.edu/ec-p/data/wooldridge/MROZ.dta
equation eq1.tobit hours nwifeinc educ exper expersq age kidslt6 kidsge6 c

' Next, we extract the fitted XB
eq1.fit(i) xb

' Get means of XB, adjusting for square of mean(exper) rather than mean of expersq
xb = xb - expersq*eq1.c(4)
scalar meanxb = @mean(xb) + @mean(exper)^2*eq1.c(4)

' The factor is given by the CDF of the normal scaled by the estimate of sigma
vector tobit_beta = eq1.@coefs
scalar sigma = tobit_beta(@rows(tobit_beta))
scalar ufactor = @cnorm(meanxb / sigma)

' The unconditional mean marginal effects are the scaled betas using the factor
vector beta = @subextract(tobit_beta, 1, 1, @rows(tobit_beta)-1)
vector ueffects = beta * ufactor


[boydb]

Glenn, Wow! Good you are at this code - for me an early Christmas present it is. You I must thank.

It all worked but the adjustment factor is 0.531 rather than 0.451(conditional on hours being positive) or 0.645 (not condition on hours - people who do and don't work) as per Wooldridge 2000 p. 545?

Regards,

Boyd

[EViews Glenn]

The ufactor (unconditional factor (17.27) in Wooldridge) should be 0.645, which it is when I run it.

If you want also want the cfactor (conditional factor (17.23) in Wooldridge) you'll have to run the modified version below. I get 0.452 which is a bit off from Wooldridge's reported 0.451, but I think it's just different rounding.

Code: Select all

' First, grab the data and perform the estimation:
wfopen http://fmwww.bc.edu/ec-p/data/wooldridge/MROZ.dta
equation eq1.tobit hours nwifeinc educ exper expersq age kidslt6 kidsge6 c

' Next, we extract the fitted XB
eq1.fit(i) xb

' Get means of XB, adjusting for square of mean(exper) rather than mean of expersq
xb = xb - expersq*eq1.c(4)
scalar meanxb = @mean(xb) + @mean(exper)^2*eq1.c(4)

' The factor is given by the CDF of the normal scaled by the estimate of sigma
vector tobit_beta = eq1.@coefs
scalar sigma = tobit_beta(@rows(tobit_beta))
scalar ufactor = @cnorm(meanxb / sigma)

' The unconditional mean marginal effects are the scaled betas using the factor
vector beta = @subextract(tobit_beta, 1, 1, @rows(tobit_beta)-1)
vector ueffects = beta * ufactor

' Mills ratio
scalar mills = @dnorm(meanxb / sigma) / ufactor

' Conditional adjustment factor and effects
scalar cfactor = (1 - mills*(meanxb / sigma + mills))
vector ceffects  = beta * cfactor


[boydb]

Glenn - I did it all again from scratch and it worked this time for me. Apologies, thank you and again Merry Christmas - this stuff would be good for the next version of the guide if possible. Regards, Boyd